01 MotionRT750簡介
MotionRT750是正運動技術首家自主自研的x86架構Windows係統或Linux係統下獨占確定CPU的強實時運動控製內核。
該方案采用獨占確定CPU內核技術實現超強性能的強實時運動控製。它將核心的運動控製、機器人算法、數控（CNC）及機器視覺等強實時的任務，集中運行在1-2個專用CPU核上。與此同時，其餘CPU核則專注於處理Windows/Linux相關的非實時任務。
此外集成MotionRT750 Runtime實shi時shi層ceng與yu操cao作zuo係xi統tong非fei實shi時shi層ceng，並bing利li用yong高gao速su共gong享xiang內nei存cun進jin行xing數shu據ju交jiao互hu，顯xian著zhu提ti升sheng了le運yun動dong控kong製zhi與yu上shang層ceng應ying用yong間jian的de通tong信xin效xiao率lv及ji函han數shu執zhi行xing速su度du，最zui終zhong實shi現xian更geng穩wen定ding、更高效的智能裝備控製，確保了運動控製任務的絕對實時性與係統穩定性，特別適用於半導體、電子裝備等高速高精的應用場合。
更多關於MotionRT750的詳情介紹與使用點擊→強實時運動控製內核MotionRT750(一)：驅動安裝、內核配置與使用。
02 認識PSO技術
PSO(position synchronized output)也就是位置同步輸出，本質上是通過采集實時的編碼器反饋位置(無編碼器可使用輸出的脈衝位置)與比較模式設定的位置進行比較，控製OP高速同步輸出信號，PSO示意圖如下。
在點膠行業中PSO一般與點膠噴射閥等設備同步輸出信號進行相位同步，在運動軌跡的所有階段以恒定的空間(或者恒定時間)間隔觸發輸出開關，包括加速、減速和勻速段，從而實現脈衝能量均勻地作用在被加工物體上。
PSO功(gong)能(neng)的(de)特(te)點(dian)就(jiu)是(shi)能(neng)高(gao)速(su)且(qie)穩(wen)定(ding)的(de)輸(shu)出(chu)信(xin)號(hao)，因(yin)為(wei)輸(shu)出(chu)精(jing)度(du)足(zu)夠(gou)高(gao)，所(suo)以(yi)能(neng)夠(gou)在(zai)整(zheng)個(ge)運(yun)動(dong)軌(gui)跡(ji)中(zhong)以(yi)固(gu)定(ding)的(de)距(ju)離(li)觸(chu)發(fa)輸(shu)出(chu)信(xin)號(hao)而(er)不(bu)用(yong)考(kao)慮(lv)總(zong)體(ti)速(su)度(du)。
03 PSO相關指令介紹
PSO功能（即硬件比較輸出）的相關命令主要有：
HW_PSWITCH2、MOVE_HWPSWITCH2、HW_TIMER等；
前兩個指令主要用於設定觸發比較輸出的距離，最後的命令是硬件定時，可配合前者使用精準控製輸出脈衝的寬度。
1.HW_PSWITCH2--總線硬件位置比較輸出（也支持脈衝軸）
比較主軸帶編碼器輸入時，自動使用編碼器位置來觸發。可以使用MOVEOP_DELAY參數來調整輸出準確時刻。
不同的總線驅動器效果可能有差異，也可以通過MOVEOP_DELAY參數來調整。
2.HW_TIMER--硬件定時器
硬件定時器，用於硬件比較輸出後一段時間後還原電平。HW_TIMER隻有1個，每次調用會強製停止之前的調用。不使用或比較完成時使用HW_TIMER(0)關閉。
HW_TIMER(mode, cyclonetime, optime, reptimes, opstate, opnum )
①mode：0-停止硬件定時器，1-動態修改參數（不修改啟動設置），2-啟動（啟動後不可重複開啟），3--停止硬件定時器（類似0，針對振鏡控製器），當前脈衝完成後不再輸出，但後麵的OP仍會繼續觸發脈衝；
②cyclonetime：周期時間，us單位；
③optime：有效時間，us單位；
④reptimes：重複次數，啟動模式，reptimes =0時，軟關閉HW_TIMER，原來的脈衝沒有完成的，會繼續輸出完成；-1時無限輸出，除非主動關閉；
⑤opstate：輸出缺省狀態，輸出口變為非此狀態後開始計時（輸出口初始狀態OFF。一般此參數設為OFF，將輸出口變為ON狀態後開始計時）；
⑥opnum：輸出口編號，必須能硬件比較輸出的口。
04 PSO在點膠中的應用
PSO功能用於點膠閥的高速開/關，直線插補和平麵圓弧插補功能用於完成加工軌跡，連續插補功能用於讓多段插補的速度連續，提高加工的效率。
在等距比較輸出模式下，不管運動速度和運動軌跡如何變化，始終固定距離進行點膠，使得點膠在空間上分布是均勻的。
上節描述的模式中，有幾種模式都能實現XY平麵的等距輸出。
例如：現有一段上左圖所示的軌跡，采用直線+圓弧+直線組成，每間隔10個距離比較輸出一次，一共比較12次，等間距輸出的方法參見下方例程的說明。
采用mode=6，矢量比較模式，結合HW_TIMER硬件定時，采用兩軸的合成矢量位置作為比較的參考坐標位置，實現上方示意圖的效果，使用方便，無需計算位置坐標，精度高。
RAPIDSTOP(2)
WAIT IDLE(0)
WAIT IDLE(1)
'基礎軸參數設置
BASE(0,1) '選擇XY軸'
ATYPE=4,4 '1-脈衝軸類型，比較DPOS；4-帶編碼器反饋軸類型，比較編碼器的反饋位置MPOS
UNITS=100,100
SPEED=100,100
ACCEL=1000,1000
DECEL=1000,1000
MERGE=ON,ON'開啟連續插補
SRAMP=50,50
OP(0,OFF)
'坐標清零
DPOS=0,0
MPOS=0,0
DIM WidthTime,Interval,StartPos,EndPos
WidthTime = 20000 '脈衝寬度20000us
Interval = 10 '脈衝間隔
StartPos = 10 '觸發起始位置
EndPos = 130 '結束位置
FORCE_SPEED=60 'SP速度
MOVEABS(0) '運動到0位
WAIT IDLE
VECTOR_MOVED = 0 '插補矢量距離清0
DIM iTime
iTime =ABS(EndPos - StartPos) \ Interval '計算比較次數
TRACE StartPos,iTime,Interval,WidthTime
HW_PSWITCH2(2) '清空HW比較緩衝區
HW_PSWITCH2(6,0,ON,StartPos,iTime,Interval) '從StrartPos觸發比較間隔Interval比較iTime次
HW_TIMER(2,WidthTime+100,WidthTime,1,OFF,0) '輸出觸發變成ON後，打開WidthTime us後關閉輸出
DELAY(10)
TRIGGER '啟動示波器
MOVEABS(50,0)
'開始運行點膠軌跡
MOVECIRCABSSP(75,25,50,25,0)
MOVEABS(75,75)
WAIT IDLE '確保
HW_PSWITCH2(2)'清空HW比較緩衝區
END
示波器采樣波形如下：采樣5個通道的波形，依次為軸0的目標位置，軸1的目標位置，輸出口0，軸0和軸1插補的矢量合成位置。
XYZ下的采樣波形：
三維情況下的PSO輸出示例：采用模式7，模式6是按指令設置的觸發距離周期輸出，模式7的輸出位置由TABLE的數據點控製，輸出位置更靈活，可實現上例等距輸出，也可實現靈活間隔的輸出。
'停止所有運動
RAPIDSTOP(2)
WAIT IDLE(0)
WAIT IDLE(1)
WAIT IDLE(2)
'軸參數設置
BASE(0,1,2) '選擇XYZ軸'
ATYPE=4,4,4 '1-脈衝軸類型，比較DPOS；4-帶編碼器反饋軸類型，比較編碼器的反饋位置MPOS
UNITS=100,100,100
SPEED=100,100,100
ACCEL=1000,1000,1000
DECEL=1000,1000,1000
MERGE=ON,ON,ON
SRAMP=50,50,50 's曲線速度平滑
OP(0,OFF) '將當前位置設置為0,0
DPOS=0,0,0
MPOS=0,0,0
FORCE_SPEED=60 'SP速度
MOVEABS(0,0,0) '運動到0位
WAIT IDLE
VECTOR_MOVED = 0 '插補矢量距離清0
DIM WidthTime,T_Startnum,Pointnum
WidthTime = 10000 '脈衝寬度10000us
T_Startnum = 0 '比較點起始table編號
Pointnum = 8 '比較點個數
TABLE(T_Startnum,10,30,50,70,90,110,130,150) '比較點坐標設置，起始table位置T_Startnum，8個點
HW_PSWITCH2(2) '清空HW比較緩衝區
HW_PSWITCH2(7,0,ON,T_Startnum,T_Startnum+Pointnum-1) '模式7
HW_TIMER(2,WidthTime+100,WidthTime,1,OFF,0) '輸出觸發變成ON後，打開WidthTime us後關閉輸出
DELAY(10)
TRIGGER '啟動示波器
MOVEABS(100,80,90) '三軸直線插補
WAIT IDLE '等待運動停止
HW_PSWITCH2(2) '清空HW比較緩衝區
END
示波器采樣波形如下：采樣8個通道的波形，依次為軸0的目標位置，軸1的目標位置，軸2的目標位置，輸出口0，軸0軸1軸2插補的矢量合成位置，軸0軸1軸2插補的運行速度。
Table存儲的比較點矢量位置為10,30,50,70,90,110,130,150，共8個點，每到一個點觸發比較，由HW_TIMER可精準控製輸出脈衝的寬度，輸出頻率更快，整體精度更高。
教學視頻可點擊→“強實時運動控製內核MotionRT750(二)：精密點膠的PSO應用”查看。
本次，正運動技術強實時運動控製內核MotionRT750(二)：精密點膠的PSO應用，就分享到這裏。
更多精彩內容請關注“正運動小助手”公眾號，需要相關開發環境與例程代碼，請谘詢正運動技術銷售工程師：400-089-8936。
本(ben)文(wen)由(you)正(zheng)運(yun)動(dong)技(ji)術(shu)原(yuan)創(chuang)，歡(huan)迎(ying)大(da)家(jia)轉(zhuan)載(zai)，共(gong)同(tong)學(xue)習(xi)，一(yi)起(qi)提(ti)高(gao)中(zhong)國(guo)智(zhi)能(neng)製(zhi)造(zao)水(shui)平(ping)。文(wen)章(zhang)版(ban)權(quan)歸(gui)正(zheng)運(yun)動(dong)技(ji)術(shu)所(suo)有(you)，如(ru)有(you)轉(zhuan)載(zai)請(qing)注(zhu)明(ming)文(wen)章(zhang)來(lai)源(yuan)。
正運動技術專注於運動控製技術研究和通用運動控製軟硬件產品的研發，是國家級高新技術企業。正運動技術彙集了來自華為、中(zhong)興(xing)等(deng)公(gong)司(si)的(de)優(you)秀(xiu)人(ren)才(cai)，在(zai)堅(jian)持(chi)自(zi)主(zhu)創(chuang)新(xin)的(de)同(tong)時(shi)，積(ji)極(ji)聯(lian)合(he)各(ge)大(da)高(gao)校(xiao)協(xie)同(tong)運(yun)動(dong)控(kong)製(zhi)基(ji)礎(chu)技(ji)術(shu)的(de)研(yan)究(jiu)，是(shi)國(guo)內(nei)工(gong)控(kong)領(ling)域(yu)發(fa)展(zhan)最(zui)快(kuai)的(de)企(qi)業(ye)之(zhi)一(yi)，也(ye)是(shi)國(guo)內(nei)少(shao)有(you)、完整掌握運動控製核心技術和實時工控軟件平台技術的企業。主要業務有：運動控製卡_運動控製器_EtherCAT運動控製卡_EtherCAT控製器_運動控製係統_視覺控製器__運動控製PLC_運動控製_機器人控製器_視覺定位_XPCIe/XPCI係列運動控製卡等等。
|
